1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
/*
* Author: Sven Gothel <sgothel@jausoft.com>
* Copyright (c) 1993-2023 Gothel Software e.K.
*
* Permission is hereby granted, free of charge, to any person obtaining
* a copy of this software and associated documentation files (the
* "Software"), to deal in the Software without restriction, including
* without limitation the rights to use, copy, modify, merge, publish,
* distribute, sublicense, and/or sell copies of the Software, and to
* permit persons to whom the Software is furnished to do so, subject to
* the following conditions:
*
* The above copyright notice and this permission notice shall be
* included in all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
* EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
* MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
* NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
* LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
* OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
* WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
*/
%top{
// This scanner is using a C++ RE/flex (always reentrant) w/ namespace
//
# include <infix_calc/infix_calc.hpp>
# include "infix_calc_parser.hpp"
# include "infix_calc_scanner_warnings.hpp"
// Code run each time a pattern is matched.
# define YY_USER_ACTION loc.columns (yyleng);
namespace infix_calc {
infix_calc_yy::parser::symbol_type make_YYEOF();
}
}
%option noyywrap nounput noinput batch
%option flex fast bison-cc bison-complete bison-cc-namespace=infix_calc_yy
%option bison-bridge
%option c++
%option namespace="infix_calc_yy"
%option lexer="scanner"
%option lex="yylex"
%option params="infix_calc_yy::location& loc"
%option token_eof="infix_calc::make_YYEOF()"
%{
namespace infix_calc {
infix_calc_yy::parser::symbol_type make_UREAL(const std::string &s, double f, const infix_calc_yy::parser::location_type& loc);
}
%}
id [a-zA-Z][a-zA-Z_0-9]*
ureal [0-9]+("."[0-9]+)?([eE][-+]?[0-9]+)?
pi [pP][iI]
blank [ \t\r]
%%
%{
// Called at yylex entry
loc.step ();
%}
{blank}+ loc.step ();
\n+ loc.lines (yyleng); loc.step ();
\( return infix_calc_yy::parser::make_LPAREN(loc);
\) return infix_calc_yy::parser::make_RPAREN(loc);
"abs" return infix_calc_yy::parser::make_ABS(loc);
"sin" return infix_calc_yy::parser::make_SIN(loc);
"cos" return infix_calc_yy::parser::make_COS(loc);
"tan" return infix_calc_yy::parser::make_TAN(loc);
"asin" return infix_calc_yy::parser::make_ARCSIN(loc);
"acos" return infix_calc_yy::parser::make_ARCCOS(loc);
"atan" return infix_calc_yy::parser::make_ARCTAN(loc);
"^" return infix_calc_yy::parser::make_POW(loc);
"sqrt" return infix_calc_yy::parser::make_SQRT(loc);
"ln" return infix_calc_yy::parser::make_LOG(loc);
"log" return infix_calc_yy::parser::make_LOG10(loc);
"exp" return infix_calc_yy::parser::make_EXP(loc);
"neg" return infix_calc_yy::parser::make_NEG(loc);
{ureal}{pi} return infix_calc::make_UREAL (yytext, M_PI, loc);
{ureal}[e] return infix_calc::make_UREAL (yytext, M_E, loc);
{ureal} return infix_calc::make_UREAL (yytext, 1.0, loc);
{pi} return infix_calc_yy::parser::make_UREAL(M_PI, loc);
[e] return infix_calc_yy::parser::make_UREAL(M_E, loc);
\- return infix_calc_yy::parser::make_SUB(loc);
"+" return infix_calc_yy::parser::make_ADD(loc);
\* return infix_calc_yy::parser::make_MUL(loc);
\/ return infix_calc_yy::parser::make_DIV(loc);
\% return infix_calc_yy::parser::make_MOD(loc);
{id} return infix_calc_yy::parser::make_IDENTIFIER(yytext, loc);
. return infix_calc_yy::parser::make_ERROR("Unrecognized characters '"+std::string(yytext)+"'", loc);
<<EOF>> return infix_calc_yy::parser::make_YYEOF (loc);
%%
|
