blob: 07143f66baed9c88abf38e7b2bd07a7d0830d818 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
|
/* Resources.Designer.cs $
This file is part of the HandBrake source code.
Homepage: <http://HandBrake.fr/>.
It may be used under the terms of the GNU General Public License. */
; Script generated by the HM NIS Edit Script Wizard.
; HM NIS Edit Wizard helper defines
!define PRODUCT_NAME "HandBrake Nightly"
!define PRODUCT_VERSION "Nightly"
!define PRODUCT_VERSION_NUMBER "Nightly"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\${PRODUCT_NAME}"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"
;Required .NET framework
!define MIN_FRA_MAJOR "4"
!define MIN_FRA_MINOR "6"
!define MIN_FRA_BUILD "*"
SetCompressor lzma
; MUI 1.67 compatible ------
!include "MUI.nsh"
!include WinVer.nsh
; MUI Settings
!define MUI_ABORTWARNING
!define MUI_ICON "HandBrakepineapple.ico"
!define MUI_UNICON "HandBrakepineapple.ico"
; Welcome page
!insertmacro MUI_PAGE_WELCOME
; License page
!insertmacro MUI_PAGE_LICENSE "doc\COPYING"
; Directory page
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!insertmacro MUI_PAGE_INSTFILES
; Finish page
;!define MUI_FINISHPAGE_RUN "$INSTDIR\HandBrake.exe"
!insertmacro MUI_PAGE_FINISH
; Uninstaller pages
!insertmacro MUI_UNPAGE_INSTFILES
; Language files
!insertmacro MUI_LANGUAGE "English"
; MUI end ------
Name "${PRODUCT_NAME}"
OutFile "HandBrake-${PRODUCT_VERSION_NUMBER}_i686-Win_GUI.exe"
!include WordFunc.nsh
!insertmacro VersionCompare
!include LogicLib.nsh
InstallDir "$PROGRAMFILES\HandBrake Nightly"
InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
ShowInstDetails show
ShowUnInstDetails show
Var InstallDotNET
Function .onInit
; For Silent Installs, Assume All Users
IfSilent 0 +2
SetShellVarContext all
; Begin Only allow one version
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "myMutex") i .r1 ?e'
Pop $R0
StrCmp $R0 0 +3
MessageBox MB_OK|MB_ICONEXCLAMATION "The installer is already running." /SD IDOK
Abort
; Detect if the intsaller is running on Windows XP and abort if it is.
${IfNot} ${AtLeastWinVista}
MessageBox MB_OK "Windows Vista with Service Pack 1 or later is required in order to run HandBrake."
Quit
${EndIf}
;Remove previous version
ReadRegStr $R0 HKLM \
"Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}\" \
"UninstallString"
StrCmp $R0 "" done
MessageBox MB_OKCANCEL|MB_ICONEXCLAMATION \
"${PRODUCT_NAME} is already installed. $\n$\nClick `OK` to remove the \
previous version or `Cancel` to continue." /SD IDOK \
IDOK uninst
goto done
;Run the uninstaller
uninst:
IfSilent +3
Exec $INSTDIR\uninst.exe
goto done
Exec '"$INSTDIR\uninst.exe" /S'
done:
FunctionEnd
Section "HandBrake" SEC01
SetOutPath "$INSTDIR"
SetOverwrite ifnewer
; Begin Check .NET version
StrCpy $InstallDotNET "No"
Call CheckFramework
StrCmp $0 "1" +3
StrCpy $InstallDotNET "Yes"
MessageBox MB_OK|MB_ICONINFORMATION "${PRODUCT_NAME} requires that the Microsoft .NET Framework 4.6 Client Profile is installed. The latest .NET Framework will be downloaded and installed automatically during installation of ${PRODUCT_NAME}." /SD IDOK
Pop $0
; Get .NET if required
${If} $InstallDotNET == "Yes"
SetDetailsView hide
inetc::get /caption "Downloading Microsoft .NET Framework 4.6" /canceltext "Cancel" "http://go.microsoft.com/fwlink/?LinkId=528222" "$INSTDIR\dotnetfx.exe" /end
Pop $1
${If} $1 != "OK"
Delete "$INSTDIR\dotnetfx.exe"
Abort "Installation cancelled, ${PRODUCT_NAME} requires the Microsoft .NET 4.6 Framework"
${EndIf}
ExecWait "$INSTDIR\dotnetfx.exe"
Delete "$INSTDIR\dotnetfx.exe"
SetDetailsView show
${EndIf}
; Install Files
File "*.exe"
CreateDirectory "$SMPROGRAMS\HandBrake Nightly"
CreateShortCut "$SMPROGRAMS\HandBrake Nightly\HandBrake Nightly.lnk" "$INSTDIR\HandBrake.exe"
CreateShortCut "$DESKTOP\HandBrake Nightly.lnk" "$INSTDIR\HandBrake.exe"
File "*.dll"
File "*.template"
File "*.config"
File "*.pdb"
; Copy the standard doc set into the doc folder
SetOutPath "$INSTDIR\doc"
SetOverwrite ifnewer
File "doc\*.*"
; Copy the standard fonts config set into the fonts folder
SetOutPath "$INSTDIR\fonts"
SetOverwrite ifnewer
File /r "fonts\*.*"
SectionEnd
Section -AdditionalIcons
CreateShortCut "$SMPROGRAMS\HandBrake Nightly\Uninstall.lnk" "$INSTDIR\uninst.exe"
SectionEnd
Section -Post
WriteUninstaller "$INSTDIR\uninst.exe"
WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\HandBrake.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\HandBrake.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
SectionEnd
Function un.onUninstSuccess
HideWindow
MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer." /SD IDOK
FunctionEnd
Function un.onInit
; For Silent Installs, Assume All Users
IfSilent 0 +2
SetShellVarContext all
MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" /SD IDYES IDYES +2
Abort
FunctionEnd
Section Uninstall
Delete "$INSTDIR\uninst.exe"
Delete "$INSTDIR\*.*"
Delete "$INSTDIR\doc\*.*"
Delete "$INSTDIR\fonts\*.*"
Delete "$INSTDIR\fonts\conf.d\*.*"
Delete "$INSTDIR\fonts\conf.avail\*.*"
RMDir "$INSTDIR\doc"
RMDIR "$INSTDIR\fonts\conf.d"
RMDIR "$INSTDIR\fonts\conf.avail"
RMDIR "$INSTDIR\fonts"
Delete "$SMPROGRAMS\HandBrake Nightly\Uninstall.lnk"
Delete "$DESKTOP\HandBrake Nightly.lnk"
Delete "$SMPROGRAMS\HandBrake Nightly\HandBrake Nightly.lnk"
RMDir "$SMPROGRAMS\HandBrake Nightly"
RMDir "$INSTDIR"
DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
SetAutoClose true
SectionEnd
;Check for .NET framework
Function CheckFrameWork
; Magic numbers from http://msdn.microsoft.com/en-us/library/ee942965.aspx
ClearErrors
ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full" "Release"
IfErrors NotDetected
${If} $0 >= 393295
StrCpy $0 "1"
${Else}
NotDetected:
StrCpy $0 "2"
${EndIf}
FunctionEnd
|
