Perform KABI checks in parallel

Reduce the time required for ./configure to perform the needed
KABI checks by allowing kbuild to compile multiple test cases in
parallel.  This was accomplished by splitting each test's source
code from the logic handling whether that code could be compiled
or not.

By introducing this split it's possible to minimize the number of
times kbuild needs to be invoked.  As importantly, it means all of
the tests can be built in parallel.  This does require a little extra
care since we expect some tests to fail, so the --keep-going (-k)
option must be provided otherwise some tests may not get compiled.
Furthermore, since a failure during the kbuild modpost phase will
result in an early exit; the final linking phase is limited to tests
which passed the initial compilation and produced an object file.

Once everything has been built the configure script proceeds as
previously.  The only significant difference is that it now merely
needs to test for the existence of a .ko file to determine the
result of a given test.  This vastly speeds up the entire process.

New test cases should use ZFS_LINUX_TEST_SRC to declare their test
source code and ZFS_LINUX_TEST_RESULT to check the result.  All of
the existing kernel-*.m4 files have been updated accordingly, see
config/kernel-current-time.m4 for a basic example.  The legacy
ZFS_LINUX_TRY_COMPILE macro has been kept to handle special cases
but it's use is not encouraged.

                  master (secs)   patched (secs)
                  -------------   ----------------
autogen.sh        61              68
configure         137             24  (~17% of current run time)
make -j $(nproc)  44              44
make rpms         287             150

Reviewed-by: Tony Hutter <[email protected]>
Signed-off-by: Brian Behlendorf <[email protected]>
Closes #8547 
Closes #9132
Closes #9341 

1 files changed, 62 insertions, 83 deletions

diff --git a/config/kernel-vfs-direct_IO.m4 b/config/kernel-vfs-direct_IO.m4
index cc50bfbe4..82583d52f 100644
--- a/config/kernel-vfs-direct_IO.m4
+++ b/config/kernel-vfs-direct_IO.m4
@@ -1,9 +1,8 @@
 dnl #
-dnl # Linux 4.6.x API change
+dnl # Check for direct IO interfaces.
 dnl #
-AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER], [
-	AC_MSG_CHECKING([whether aops->direct_IO() uses iov_iter])
-	ZFS_LINUX_TRY_COMPILE([
+AC_DEFUN([ZFS_AC_KERNEL_SRC_VFS_DIRECT_IO], [
+	ZFS_LINUX_TEST_SRC([direct_io_iter], [
 		#include <linux/fs.h>
 
 		ssize_t test_direct_IO(struct kiocb *kiocb,
@@ -13,24 +12,9 @@ AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER], [
 		    aops __attribute__ ((unused)) = {
 			.direct_IO = test_direct_IO,
 		};
-	],[
-	],[
-		AC_MSG_RESULT([yes])
-		AC_DEFINE(HAVE_VFS_DIRECT_IO_ITER, 1,
-		    [aops->direct_IO() uses iov_iter without rw])
-		zfs_ac_direct_io="yes"
-	],[
-		AC_MSG_RESULT([no])
-	])
-])
+	],[])
 
-dnl #
-dnl # Linux 4.1.x API change
-dnl #
-AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER_OFFSET], [
-	AC_MSG_CHECKING(
-	    [whether aops->direct_IO() uses iov_iter with offset])
-	ZFS_LINUX_TRY_COMPILE([
+	ZFS_LINUX_TEST_SRC([direct_io_iter_offset], [
 		#include <linux/fs.h>
 
 		ssize_t test_direct_IO(struct kiocb *kiocb,
@@ -40,24 +24,9 @@ AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER_OFFSET], [
 		    aops __attribute__ ((unused)) = {
 			.direct_IO = test_direct_IO,
 		};
-	],[
-	],[
-		AC_MSG_RESULT([yes])
-		AC_DEFINE(HAVE_VFS_DIRECT_IO_ITER_OFFSET, 1,
-		    [aops->direct_IO() uses iov_iter with offset])
-		zfs_ac_direct_io="yes"
-	],[
-		AC_MSG_RESULT([no])
-	])
-])
+	],[])
 
-dnl #
-dnl # Linux 3.16.x API change
-dnl #
-AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER_RW_OFFSET], [
-	AC_MSG_CHECKING(
-	    [whether aops->direct_IO() uses iov_iter with rw and offset])
-	ZFS_LINUX_TRY_COMPILE([
+	ZFS_LINUX_TEST_SRC([direct_io_iter_rw_offset], [
 		#include <linux/fs.h>
 
 		ssize_t test_direct_IO(int rw, struct kiocb *kiocb,
@@ -67,23 +36,9 @@ AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER_RW_OFFSET], [
 		    aops __attribute__ ((unused)) = {
 		    .direct_IO = test_direct_IO,
 		};
-	],[
-	],[
-		AC_MSG_RESULT([yes])
-		AC_DEFINE(HAVE_VFS_DIRECT_IO_ITER_RW_OFFSET, 1,
-		    [aops->direct_IO() uses iov_iter with rw and offset])
-		zfs_ac_direct_io="yes"
-	],[
-		AC_MSG_RESULT([no])
-	])
-])
+	],[])
 
-dnl #
-dnl # Ancient Linux API (predates git)
-dnl #
-AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_IOVEC], [
-	AC_MSG_CHECKING([whether aops->direct_IO() uses iovec])
-	ZFS_LINUX_TRY_COMPILE([
+	ZFS_LINUX_TEST_SRC([direct_io_iovec], [
 		#include <linux/fs.h>
 
 		ssize_t test_direct_IO(int rw, struct kiocb *kiocb,
@@ -94,37 +49,61 @@ AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO_IOVEC], [
 		    aops __attribute__ ((unused)) = {
 		    .direct_IO = test_direct_IO,
 		};
-	],[
-	],[
-		AC_MSG_RESULT([yes])
-		AC_DEFINE(HAVE_VFS_DIRECT_IO_IOVEC, 1,
-		    [aops->direct_IO() uses iovec])
-		zfs_ac_direct_io="yes"
-	],[
-		AC_MSG_RESULT([no])
-	])
+	],[])
 ])
 
 AC_DEFUN([ZFS_AC_KERNEL_VFS_DIRECT_IO], [
-	zfs_ac_direct_io="no"
-
-	if test "$zfs_ac_direct_io" = "no"; then
-		ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER
-	fi
-
-	if test "$zfs_ac_direct_io" = "no"; then
-		ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER_OFFSET
-	fi
-
-	if test "$zfs_ac_direct_io" = "no"; then
-		ZFS_AC_KERNEL_VFS_DIRECT_IO_ITER_RW_OFFSET
-	fi
-
-	if test "$zfs_ac_direct_io" = "no"; then
-		ZFS_AC_KERNEL_VFS_DIRECT_IO_IOVEC
-	fi
+	dnl #
+	dnl # Linux 4.6.x API change
+	dnl #
+	AC_MSG_CHECKING([whether aops->direct_IO() uses iov_iter])
+	ZFS_LINUX_TEST_RESULT([direct_io_iter], [
+		AC_MSG_RESULT([yes])
+		AC_DEFINE(HAVE_VFS_DIRECT_IO_ITER, 1,
+		    [aops->direct_IO() uses iov_iter without rw])
+	],[
+		AC_MSG_RESULT([no])
 
-	if test "$zfs_ac_direct_io" = "no"; then
-		AC_MSG_ERROR([no; unknown direct IO interface])
-	fi
+		dnl #
+		dnl # Linux 4.1.x API change
+		dnl #
+		AC_MSG_CHECKING(
+		    [whether aops->direct_IO() uses offset])
+		ZFS_LINUX_TEST_RESULT([direct_io_iter_offset], [
+			AC_MSG_RESULT([yes])
+			AC_DEFINE(HAVE_VFS_DIRECT_IO_ITER_OFFSET, 1,
+			    [aops->direct_IO() uses iov_iter with offset])
+
+		],[
+			AC_MSG_RESULT([no])
+
+			dnl #
+			dnl # Linux 3.16.x API change
+			dnl #
+			AC_MSG_CHECKING(
+			    [whether aops->direct_IO() uses rw and offset])
+			ZFS_LINUX_TEST_RESULT([direct_io_iter_rw_offset], [
+				AC_MSG_RESULT([yes])
+				AC_DEFINE(HAVE_VFS_DIRECT_IO_ITER_RW_OFFSET, 1,
+				    [aops->direct_IO() uses iov_iter with ]
+				    [rw and offset])
+			],[
+				AC_MSG_RESULT([no])
+
+				dnl #
+				dnl # Ancient Linux API (predates git)
+				dnl #
+				AC_MSG_CHECKING(
+				    [whether aops->direct_IO() uses iovec])
+				ZFS_LINUX_TEST_RESULT([direct_io_iovec], [
+					AC_MSG_RESULT([yes])
+					AC_DEFINE(HAVE_VFS_DIRECT_IO_IOVEC, 1,
+					    [aops->direct_IO() uses iovec])
+				],[
+					ZFS_LINUX_TEST_ERROR([direct IO])
+					AC_MSG_RESULT([no])
+				])
+			])
+		])
+	])
 ])