Perform KABI checks in parallel

Reduce the time required for ./configure to perform the needed
KABI checks by allowing kbuild to compile multiple test cases in
parallel.  This was accomplished by splitting each test's source
code from the logic handling whether that code could be compiled
or not.

By introducing this split it's possible to minimize the number of
times kbuild needs to be invoked.  As importantly, it means all of
the tests can be built in parallel.  This does require a little extra
care since we expect some tests to fail, so the --keep-going (-k)
option must be provided otherwise some tests may not get compiled.
Furthermore, since a failure during the kbuild modpost phase will
result in an early exit; the final linking phase is limited to tests
which passed the initial compilation and produced an object file.

Once everything has been built the configure script proceeds as
previously.  The only significant difference is that it now merely
needs to test for the existence of a .ko file to determine the
result of a given test.  This vastly speeds up the entire process.

New test cases should use ZFS_LINUX_TEST_SRC to declare their test
source code and ZFS_LINUX_TEST_RESULT to check the result.  All of
the existing kernel-*.m4 files have been updated accordingly, see
config/kernel-current-time.m4 for a basic example.  The legacy
ZFS_LINUX_TRY_COMPILE macro has been kept to handle special cases
but it's use is not encouraged.

                  master (secs)   patched (secs)
                  -------------   ----------------
autogen.sh        61              68
configure         137             24  (~17% of current run time)
make -j $(nproc)  44              44
make rpms         287             150

Reviewed-by: Tony Hutter <[email protected]>
Signed-off-by: Brian Behlendorf <[email protected]>
Closes #8547
Closes #9132
Closes #9341
Conflicts:
	Makefile.am
	config/kernel-fpu.m4

1 files changed, 29 insertions, 28 deletions

diff --git a/config/kernel-put-link.m4 b/config/kernel-put-link.m4
index a0bb36ef2..f03df9e99 100644
--- a/config/kernel-put-link.m4
+++ b/config/kernel-put-link.m4
@@ -1,17 +1,35 @@
 dnl #
 dnl # Supported symlink APIs
 dnl #
+AC_DEFUN([ZFS_AC_KERNEL_SRC_PUT_LINK], [
+	ZFS_LINUX_TEST_SRC([put_link_cookie], [
+		#include <linux/fs.h>
+		void put_link(struct inode *ip, void *cookie)
+		    { return; }
+		static struct inode_operations
+		    iops __attribute__ ((unused)) = {
+			.put_link = put_link,
+		};
+	],[])
+
+	ZFS_LINUX_TEST_SRC([put_link_nameidata], [
+		#include <linux/fs.h>
+		void put_link(struct dentry *de, struct
+		    nameidata *nd, void *ptr) { return; }
+		static struct inode_operations
+		    iops __attribute__ ((unused)) = {
+			.put_link = put_link,
+		};
+	],[])
+])
+
 AC_DEFUN([ZFS_AC_KERNEL_PUT_LINK], [
 	dnl #
 	dnl # 4.5 API change
 	dnl # get_link() uses delayed done, there is no put_link() interface.
+	dnl # This check intially uses the inode_operations_get_link result
 	dnl #
-	ZFS_LINUX_TRY_COMPILE([
-		#if !defined(HAVE_GET_LINK_DELAYED)
-		#error "Expecting get_link() delayed done"
-		#endif
-	],[
-	],[
+	ZFS_LINUX_TEST_RESULT([inode_operations_get_link], [
 		AC_DEFINE(HAVE_PUT_LINK_DELAYED, 1, [iops->put_link() delayed])
 	],[
 		dnl #
@@ -19,41 +37,24 @@ AC_DEFUN([ZFS_AC_KERNEL_PUT_LINK], [
 		dnl # This kernel retired the nameidata structure.
 		dnl #
 		AC_MSG_CHECKING([whether iops->put_link() passes cookie])
-		ZFS_LINUX_TRY_COMPILE([
-			#include <linux/fs.h>
-			void put_link(struct inode *ip, void *cookie)
-			    { return; }
-			static struct inode_operations
-			    iops __attribute__ ((unused)) = {
-				.put_link = put_link,
-			};
-		],[
-		],[
+		ZFS_LINUX_TEST_RESULT([put_link_cookie], [
 			AC_MSG_RESULT(yes)
 			AC_DEFINE(HAVE_PUT_LINK_COOKIE, 1,
 			    [iops->put_link() cookie])
 		],[
+			AC_MSG_RESULT(no)
+
 			dnl #
 			dnl # 2.6.32 API
 			dnl #
-			AC_MSG_RESULT(no)
 			AC_MSG_CHECKING(
 			    [whether iops->put_link() passes nameidata])
-			ZFS_LINUX_TRY_COMPILE([
-				#include <linux/fs.h>
-				void put_link(struct dentry *de, struct
-				    nameidata *nd, void *ptr) { return; }
-				static struct inode_operations
-				    iops __attribute__ ((unused)) = {
-					.put_link = put_link,
-				};
-			],[
-			],[
+			ZFS_LINUX_TEST_RESULT([put_link_nameidata], [
 				AC_MSG_RESULT(yes)
 				AC_DEFINE(HAVE_PUT_LINK_NAMEIDATA, 1,
 				    [iops->put_link() nameidata])
 			],[
-				AC_MSG_ERROR(no; please file a bug report)
+				ZFS_LINUX_TEST_ERROR([put_link])
 			])
 		])
 	])