Perform KABI checks in parallel

Reduce the time required for ./configure to perform the needed
KABI checks by allowing kbuild to compile multiple test cases in
parallel.  This was accomplished by splitting each test's source
code from the logic handling whether that code could be compiled
or not.

By introducing this split it's possible to minimize the number of
times kbuild needs to be invoked.  As importantly, it means all of
the tests can be built in parallel.  This does require a little extra
care since we expect some tests to fail, so the --keep-going (-k)
option must be provided otherwise some tests may not get compiled.
Furthermore, since a failure during the kbuild modpost phase will
result in an early exit; the final linking phase is limited to tests
which passed the initial compilation and produced an object file.

Once everything has been built the configure script proceeds as
previously.  The only significant difference is that it now merely
needs to test for the existence of a .ko file to determine the
result of a given test.  This vastly speeds up the entire process.

New test cases should use ZFS_LINUX_TEST_SRC to declare their test
source code and ZFS_LINUX_TEST_RESULT to check the result.  All of
the existing kernel-*.m4 files have been updated accordingly, see
config/kernel-current-time.m4 for a basic example.  The legacy
ZFS_LINUX_TRY_COMPILE macro has been kept to handle special cases
but it's use is not encouraged.

                  master (secs)   patched (secs)
                  -------------   ----------------
autogen.sh        61              68
configure         137             24  (~17% of current run time)
make -j $(nproc)  44              44
make rpms         287             150

Reviewed-by: Tony Hutter <[email protected]>
Signed-off-by: Brian Behlendorf <[email protected]>
Closes #8547 
Closes #9132
Closes #9341 

1 files changed, 65 insertions, 61 deletions

diff --git a/config/kernel-get-link.m4 b/config/kernel-get-link.m4
index 3cda08c1b..e4f478e37 100644
--- a/config/kernel-get-link.m4
+++ b/config/kernel-get-link.m4
@@ -1,13 +1,29 @@
 dnl #
 dnl # Supported get_link() interfaces checked newest to oldest.
+dnl # Note this interface used to be named follow_link.
 dnl #
-AC_DEFUN([ZFS_AC_KERNEL_FOLLOW_LINK], [
-	dnl #
-	dnl # 4.2 API change
-	dnl # - This kernel retired the nameidata structure.
-	dnl #
-	AC_MSG_CHECKING([whether iops->follow_link() passes cookie])
-	ZFS_LINUX_TRY_COMPILE([
+AC_DEFUN([ZFS_AC_KERNEL_SRC_GET_LINK], [
+	ZFS_LINUX_TEST_SRC([inode_operations_get_link], [
+		#include <linux/fs.h>
+		const char *get_link(struct dentry *de, struct inode *ip,
+		    struct delayed_call *done) { return "symlink"; }
+		static struct inode_operations
+		     iops __attribute__ ((unused)) = {
+			.get_link = get_link,
+		};
+	],[])
+
+	ZFS_LINUX_TEST_SRC([inode_operations_get_link_cookie], [
+		#include <linux/fs.h>
+		const char *get_link(struct dentry *de, struct
+		    inode *ip, void **cookie) { return "symlink"; }
+		static struct inode_operations
+		     iops __attribute__ ((unused)) = {
+			.get_link = get_link,
+		};
+	],[])
+
+	ZFS_LINUX_TEST_SRC([inode_operations_follow_link], [
 		#include <linux/fs.h>
 		const char *follow_link(struct dentry *de,
 		    void **cookie) { return "symlink"; }
@@ -15,35 +31,17 @@ AC_DEFUN([ZFS_AC_KERNEL_FOLLOW_LINK], [
 		    iops __attribute__ ((unused)) = {
 			.follow_link = follow_link,
 		};
-	],[
-	],[
-		AC_MSG_RESULT(yes)
-		AC_DEFINE(HAVE_FOLLOW_LINK_COOKIE, 1,
-		    [iops->follow_link() cookie])
-	],[
-		dnl #
-		dnl # 2.6.32 API
-		dnl #
-		AC_MSG_RESULT(no)
-		AC_MSG_CHECKING(
-		   [whether iops->follow_link() passes nameidata])
-		ZFS_LINUX_TRY_COMPILE([
+	],[])
+
+	ZFS_LINUX_TEST_SRC([inode_operations_follow_link_nameidata], [
 		#include <linux/fs.h>
-			void *follow_link(struct dentry *de, struct
-			    nameidata *nd) { return (void *)NULL; }
-			static struct inode_operations
-			    iops __attribute__ ((unused)) = {
-				.follow_link = follow_link,
-			};
-		],[
-		],[
-			AC_MSG_RESULT(yes)
-			AC_DEFINE(HAVE_FOLLOW_LINK_NAMEIDATA, 1,
-			          [iops->follow_link() nameidata])
-		],[
-			AC_MSG_ERROR(no; please file a bug report)
-		])
-	])
+		void *follow_link(struct dentry *de, struct
+		    nameidata *nd) { return (void *)NULL; }
+		static struct inode_operations
+		    iops __attribute__ ((unused)) = {
+			.follow_link = follow_link,
+		};
+	],[])
 ])
 
 AC_DEFUN([ZFS_AC_KERNEL_GET_LINK], [
@@ -53,20 +51,12 @@ AC_DEFUN([ZFS_AC_KERNEL_GET_LINK], [
 	dnl # used it to retire the put_link() interface.
 	dnl #
 	AC_MSG_CHECKING([whether iops->get_link() passes delayed])
-	ZFS_LINUX_TRY_COMPILE([
-		#include <linux/fs.h>
-		const char *get_link(struct dentry *de, struct inode *ip,
-		    struct delayed_call *done) { return "symlink"; }
-		static struct inode_operations
-		     iops __attribute__ ((unused)) = {
-			.get_link = get_link,
-		};
-	],[
-	],[
+	ZFS_LINUX_TEST_RESULT([inode_operations_get_link], [
 		AC_MSG_RESULT(yes)
-		AC_DEFINE(HAVE_GET_LINK_DELAYED, 1,
-		    [iops->get_link() delayed])
+		AC_DEFINE(HAVE_GET_LINK_DELAYED, 1, [iops->get_link() delayed])
 	],[
+		AC_MSG_RESULT(no)
+
 		dnl #
 		dnl # 4.5 API change
 		dnl # The follow_link() interface has been replaced by
@@ -74,27 +64,41 @@ AC_DEFUN([ZFS_AC_KERNEL_GET_LINK], [
 		dnl # - An inode is passed as a separate argument
 		dnl # - When called in RCU mode a NULL dentry is passed.
 		dnl #
-		AC_MSG_RESULT(no)
 		AC_MSG_CHECKING([whether iops->get_link() passes cookie])
-		ZFS_LINUX_TRY_COMPILE([
-			#include <linux/fs.h>
-			const char *get_link(struct dentry *de, struct
-			    inode *ip, void **cookie) { return "symlink"; }
-			static struct inode_operations
-			     iops __attribute__ ((unused)) = {
-				.get_link = get_link,
-			};
-		],[
-		],[
+		ZFS_LINUX_TEST_RESULT([inode_operations_get_link_cookie], [
 			AC_MSG_RESULT(yes)
 			AC_DEFINE(HAVE_GET_LINK_COOKIE, 1,
 			    [iops->get_link() cookie])
 		],[
+			AC_MSG_RESULT(no)
+
 			dnl #
-			dnl # Check for the follow_link APIs.
+			dnl # 4.2 API change
+			dnl # This kernel retired the nameidata structure.
 			dnl #
-			AC_MSG_RESULT(no)
-			ZFS_AC_KERNEL_FOLLOW_LINK
+			AC_MSG_CHECKING(
+			    [whether iops->follow_link() passes cookie])
+			ZFS_LINUX_TEST_RESULT([inode_operations_follow_link], [
+				AC_MSG_RESULT(yes)
+				AC_DEFINE(HAVE_FOLLOW_LINK_COOKIE, 1,
+				    [iops->follow_link() cookie])
+			],[
+				AC_MSG_RESULT(no)
+
+				dnl #
+				dnl # 2.6.32 API
+				dnl #
+				AC_MSG_CHECKING(
+				[whether iops->follow_link() passes nameidata])
+				ZFS_LINUX_TEST_RESULT(
+				    [inode_operations_follow_link_nameidata],[
+					AC_MSG_RESULT(yes)
+					AC_DEFINE(HAVE_FOLLOW_LINK_NAMEIDATA, 1,
+					    [iops->follow_link() nameidata])
+				],[
+					ZFS_LINUX_TEST_ERROR([get_link])
+				])
+			])
 		])
 	])
 ])