Update SAs when an inode is dirtied

Revert the portion of commit d3aa3ea which always resulted in the
SAs being update when an mmap()'ed file was closed.  That change
accidentally resulted in unexpected ctime updates which upset tools
like git.  That was always a horrible hack and I'm happy it will
never make it in to a tagged release.

The right fix is something I initially resisted doing because I
was worried about the additional overhead.  However, in hindsight
the overhead isn't as bad as I feared.

This patch implemented the sops->dirty_inode() callback which is
unsurprisingly called when an inode is dirtied.  We leverage this
callback to keep the znode SAs strictly in sync with the inode.

However, for now we're going to go slowly to avoid introducing
any new unexpected issues by only updating the atime, mtime, and
ctime.  This will cover the callpath of most concern to us.

  ->filemap_page_mkwrite->file_update_time->update_time->
      mark_inode_dirty_sync->__mark_inode_dirty->dirty_inode

Signed-off-by: Brian Behlendorf <[email protected]>
Closes #764
Closes #1140

1 files changed, 23 insertions, 0 deletions

diff --git a/config/kernel-dirty-inode.m4 b/config/kernel-dirty-inode.m4
new file mode 100644
index 000000000..2ededf154
--- /dev/null
+++ b/config/kernel-dirty-inode.m4
@@ -0,0 +1,23 @@
+dnl #
+dnl # 3.0 API change
+dnl # The sops->dirty_inode() callbacks were updated to take a flags
+dnl # argument.  This allows the greater control over whether the
+dnl # filesystem needs to push out a transaction or not.
+dnl #
+AC_DEFUN([ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS], [
+	AC_MSG_CHECKING([whether sops->dirty_inode() wants flags])
+	ZFS_LINUX_TRY_COMPILE([
+		#include <linux/fs.h>
+	],[
+		void (*dirty_inode) (struct inode *, int) = NULL;
+		struct super_operations sops __attribute__ ((unused));
+
+		sops.dirty_inode = dirty_inode;
+	],[
+		AC_MSG_RESULT([yes])
+		AC_DEFINE(HAVE_DIRTY_INODE_WITH_FLAGS, 1,
+			[sops->dirty_inode() wants flags])
+	],[
+		AC_MSG_RESULT([no])
+	])
+])