Perform KABI checks in parallel

Reduce the time required for ./configure to perform the needed
KABI checks by allowing kbuild to compile multiple test cases in
parallel.  This was accomplished by splitting each test's source
code from the logic handling whether that code could be compiled
or not.

By introducing this split it's possible to minimize the number of
times kbuild needs to be invoked.  As importantly, it means all of
the tests can be built in parallel.  This does require a little extra
care since we expect some tests to fail, so the --keep-going (-k)
option must be provided otherwise some tests may not get compiled.
Furthermore, since a failure during the kbuild modpost phase will
result in an early exit; the final linking phase is limited to tests
which passed the initial compilation and produced an object file.

Once everything has been built the configure script proceeds as
previously.  The only significant difference is that it now merely
needs to test for the existence of a .ko file to determine the
result of a given test.  This vastly speeds up the entire process.

New test cases should use ZFS_LINUX_TEST_SRC to declare their test
source code and ZFS_LINUX_TEST_RESULT to check the result.  All of
the existing kernel-*.m4 files have been updated accordingly, see
config/kernel-current-time.m4 for a basic example.  The legacy
ZFS_LINUX_TRY_COMPILE macro has been kept to handle special cases
but it's use is not encouraged.

                  master (secs)   patched (secs)
                  -------------   ----------------
autogen.sh        61              68
configure         137             24  (~17% of current run time)
make -j $(nproc)  44              44
make rpms         287             150

Reviewed-by: Tony Hutter <[email protected]>
Signed-off-by: Brian Behlendorf <[email protected]>
Closes #8547 
Closes #9132
Closes #9341 

1 files changed, 52 insertions, 26 deletions

diff --git a/config/kernel-bdi.m4 b/config/kernel-bdi.m4
index cb7479ee9..51516332a 100644
--- a/config/kernel-bdi.m4
+++ b/config/kernel-bdi.m4
@@ -1,55 +1,81 @@
 dnl #
-dnl # 2.6.32 - 2.6.33, bdi_setup_and_register() is not exported.
-dnl # 2.6.34 - 3.19, bdi_setup_and_register() takes 3 arguments.
-dnl # 4.0 - 4.11, bdi_setup_and_register() takes 2 arguments.
-dnl # 4.12 - x.y, super_setup_bdi_name() new interface.
+dnl # Check available BDI interfaces.
 dnl #
-AC_DEFUN([ZFS_AC_KERNEL_BDI], [
-	AC_MSG_CHECKING([whether super_setup_bdi_name() exists])
-	ZFS_LINUX_TRY_COMPILE_SYMBOL([
+AC_DEFUN([ZFS_AC_KERNEL_SRC_BDI], [
+	ZFS_LINUX_TEST_SRC([super_setup_bdi_name], [
 		#include <linux/fs.h>
 		struct super_block sb;
 	], [
 		char *name = "bdi";
 		atomic_long_t zfs_bdi_seq;
 		int error __attribute__((unused)) =
-		    super_setup_bdi_name(&sb, "%.28s-%ld", name, atomic_long_inc_return(&zfs_bdi_seq));
-	], [super_setup_bdi_name], [fs/super.c], [
+		    super_setup_bdi_name(&sb, "%.28s-%ld", name,
+		    atomic_long_inc_return(&zfs_bdi_seq));
+	])
+
+	ZFS_LINUX_TEST_SRC([bdi_setup_and_register], [
+		#include <linux/backing-dev.h>
+		struct backing_dev_info bdi;
+	], [
+		char *name = "bdi";
+		int error __attribute__((unused)) =
+		    bdi_setup_and_register(&bdi, name);
+	])
+
+	ZFS_LINUX_TEST_SRC([bdi_setup_and_register_3args], [
+		#include <linux/backing-dev.h>
+		struct backing_dev_info bdi;
+	], [
+		char *name = "bdi";
+		unsigned int cap = BDI_CAP_MAP_COPY;
+		int error __attribute__((unused)) =
+		    bdi_setup_and_register(&bdi, name, cap);
+	])
+])
+
+AC_DEFUN([ZFS_AC_KERNEL_BDI], [
+	dnl #
+	dnl # 4.12, super_setup_bdi_name() introduced.
+	dnl #
+	AC_MSG_CHECKING([whether super_setup_bdi_name() exists])
+	ZFS_LINUX_TEST_RESULT_SYMBOL([super_setup_bdi_name],
+	    [super_setup_bdi_name], [fs/super.c], [
 		AC_MSG_RESULT(yes)
 		AC_DEFINE(HAVE_SUPER_SETUP_BDI_NAME, 1,
                     [super_setup_bdi_name() exits])
 	], [
 		AC_MSG_RESULT(no)
+
+		dnl #
+		dnl # 4.0 - 4.11, bdi_setup_and_register() takes 2 arguments.
+		dnl #
 		AC_MSG_CHECKING(
 		    [whether bdi_setup_and_register() wants 2 args])
-		ZFS_LINUX_TRY_COMPILE_SYMBOL([
-			#include <linux/backing-dev.h>
-			struct backing_dev_info bdi;
-		], [
-			char *name = "bdi";
-			int error __attribute__((unused)) =
-			    bdi_setup_and_register(&bdi, name);
-		], [bdi_setup_and_register], [mm/backing-dev.c], [
+		ZFS_LINUX_TEST_RESULT_SYMBOL([bdi_setup_and_register],
+		    [bdi_setup_and_register], [mm/backing-dev.c], [
 			AC_MSG_RESULT(yes)
 			AC_DEFINE(HAVE_2ARGS_BDI_SETUP_AND_REGISTER, 1,
 			    [bdi_setup_and_register() wants 2 args])
 		], [
 			AC_MSG_RESULT(no)
+
+			dnl #
+			dnl # 2.6.34 - 3.19, bdi_setup_and_register()
+			dnl # takes 3 arguments.
+			dnl #
 			AC_MSG_CHECKING(
 			    [whether bdi_setup_and_register() wants 3 args])
-			ZFS_LINUX_TRY_COMPILE_SYMBOL([
-				#include <linux/backing-dev.h>
-				struct backing_dev_info bdi;
-			], [
-				char *name = "bdi";
-				unsigned int cap = BDI_CAP_MAP_COPY;
-				int error __attribute__((unused)) =
-				    bdi_setup_and_register(&bdi, name, cap);
-			], [bdi_setup_and_register], [mm/backing-dev.c], [
+			ZFS_LINUX_TEST_RESULT_SYMBOL(
+			    [bdi_setup_and_register_3args],
+			    [bdi_setup_and_register], [mm/backing-dev.c], [
 				AC_MSG_RESULT(yes)
 				AC_DEFINE(HAVE_3ARGS_BDI_SETUP_AND_REGISTER, 1,
 				    [bdi_setup_and_register() wants 3 args])
 			], [
+				dnl #
+				dnl # 2.6.32 - 2.6.33, bdi_setup_and_register()
+				dnl # is not exported.
+				dnl #
 				AC_MSG_RESULT(no)
 			])
 		])