Always check -Wno-unused-but-set-variable gcc support

The previous commit 8a7e1ceefa430988c8f888ca708ab307333b4464 wasn't
quite right.  This check applies to both the user and kernel space
build and as such we must make sure it runs regardless of what
the --with-config option is set too.

For example, if --with-config=kernel then the autoconf test does
not run and we generate build warnings when compiling the kernel
packages.

1 files changed, 27 insertions, 0 deletions

diff --git a/config/always-no-unused-but-set-variable.m4 b/config/always-no-unused-but-set-variable.m4
new file mode 100644
index 000000000..0e2634da2
--- /dev/null
+++ b/config/always-no-unused-but-set-variable.m4
@@ -0,0 +1,27 @@
+dnl #
+dnl # Check if gcc supports -Wno-unused-but-set-variable option.
+dnl #
+dnl # We actually invoke gcc with the -Wunused-but-set-variable option
+dnl # and infer the 'no-' version does or doesn't exist based upon
+dnl # the results.  This is required because when checking any of
+dnl # no- prefixed options gcc always returns success.
+dnl #
+AC_DEFUN([ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE], [
+	AC_MSG_CHECKING([for -Wno-unused-but-set-variable support])
+
+	saved_flags="$CFLAGS"
+	CFLAGS="$CFLAGS -Wunused-but-set-variable"
+
+	AC_RUN_IFELSE(AC_LANG_PROGRAM( [], []),
+	[
+		NO_UNUSED_BUT_SET_VARIABLE=-Wno-unused-but-set-variable
+		AC_MSG_RESULT([yes])
+	],
+	[
+		NO_UNUSED_BUT_SET_VARIABLE=
+		AC_MSG_RESULT([no])
+	])
+
+	CFLAGS="$saved_flags"
+	AC_SUBST([NO_UNUSED_BUT_SET_VARIABLE])
+])