Replace the ZFS_AC_META perl dependency with awk

The only remaining perl dependency is part of the ZFS_AC_META macro.
By eliminating this and replacing it with awk we can avoid the need
to pull in perl to rebuild the packages.

Signed-off-by: Brian Behlendorf <[email protected]>
Issue #1380

1 files changed, 56 insertions, 31 deletions

diff --git a/config/zfs-meta.m4 b/config/zfs-meta.m4
index 2deda715d..03a15db36 100644
--- a/config/zfs-meta.m4
+++ b/config/zfs-meta.m4
@@ -1,14 +1,35 @@
-###############################################################################
-# Written by Chris Dunlap <[email protected]>.
-# Modified by Brian Behlendorf <[email protected]>.
-###############################################################################
-# ZFS_AC_META: Read metadata from the META file.  When building from a
-# git repository the ZFS_META_RELEASE field will be overwritten if there
-# is an annotated tag matching the form ZFS_META_NAME-ZFS_META_VERSION-*.
-# This allows for working builds to be uniquely identified using the git
-# commit hash.
-###############################################################################
-
+dnl #
+dnl # DESCRIPTION:
+dnl # Read meta data from the META file.  When building from a git repository
+dnl # the ZFS_META_RELEASE field will be overwritten if there is an annotated
+dnl # tag matching the form ZFS_META_NAME-ZFS_META_VERSION-*.  This allows
+dnl # for working builds to be uniquely identified using the git commit hash.
+dnl #
+dnl #    The META file format is as follows:
+dnl #      ^[ ]*KEY:[ \t]+VALUE$
+dnl #
+dnl #    In other words:
+dnl #    - KEY is separated from VALUE by a colon and one or more spaces/tabs.
+dnl #    - KEY and VALUE are case sensitive.
+dnl #    - Leading spaces are ignored.
+dnl #    - First match wins for duplicate keys.
+dnl #
+dnl #    A line can be commented out by preceding it with a '#' (or technically
+dnl #    any non-space character since that will prevent the regex from
+dnl #    matching).
+dnl #
+dnl # WARNING:
+dnl #   Placing a colon followed by a space or tab (ie, ":[ \t]+") within the
+dnl #   VALUE will prematurely terminate the string since that sequence is
+dnl #   used as the awk field separator.
+dnl #
+dnl # KEYS:
+dnl #   The following META keys are recognized:
+dnl #     Name, Version, Release, Date, Author, LT_Current, LT_Revision, LT_Age
+dnl #
+dnl # Written by Chris Dunlap <[email protected]>.
+dnl # Modified by Brian Behlendorf <[email protected]>.
+dnl #
 AC_DEFUN([ZFS_AC_META], [
 
 	AH_BOTTOM([
@@ -21,6 +42,7 @@ AC_DEFUN([ZFS_AC_META], [
 #undef STDC_HEADERS
 #undef VERSION])
 
+	AC_PROG_AWK
 	AC_MSG_CHECKING([metadata])
 
 	META="$srcdir/META"
@@ -28,7 +50,7 @@ AC_DEFUN([ZFS_AC_META], [
 	if test -f "$META"; then
 		_zfs_ac_meta_type="META file"
 
-		ZFS_META_NAME=_ZFS_AC_META_GETVAL([(?:NAME|PROJECT|PACKAGE)]);
+		ZFS_META_NAME=_ZFS_AC_META_GETVAL([(Name|Project|Package)]);
 		if test -n "$ZFS_META_NAME"; then
 			AC_DEFINE_UNQUOTED([ZFS_META_NAME], ["$ZFS_META_NAME"],
 				[Define the project name.]
@@ -36,7 +58,7 @@ AC_DEFUN([ZFS_AC_META], [
 			AC_SUBST([ZFS_META_NAME])
 		fi
 
-		ZFS_META_VERSION=_ZFS_AC_META_GETVAL([VERSION]);
+		ZFS_META_VERSION=_ZFS_AC_META_GETVAL([Version]);
 		if test -n "$ZFS_META_VERSION"; then
 			AC_DEFINE_UNQUOTED([ZFS_META_VERSION], ["$ZFS_META_VERSION"],
 				[Define the project version.]
@@ -44,7 +66,7 @@ AC_DEFUN([ZFS_AC_META], [
 			AC_SUBST([ZFS_META_VERSION])
 		fi
 
-		ZFS_META_RELEASE=_ZFS_AC_META_GETVAL([RELEASE]);
+		ZFS_META_RELEASE=_ZFS_AC_META_GETVAL([Release]);
 		if git rev-parse --git-dir > /dev/null 2>&1; then
 			_match="${ZFS_META_NAME}-${ZFS_META_VERSION}*"
 			_alias=$(git describe --match=${_match} 2>/dev/null)
@@ -65,7 +87,7 @@ AC_DEFUN([ZFS_AC_META], [
 			AC_SUBST([RELEASE])
 		fi
 
-		ZFS_META_LICENSE=_ZFS_AC_META_GETVAL([LICENSE]);
+		ZFS_META_LICENSE=_ZFS_AC_META_GETVAL([License]);
 		if test -n "$ZFS_META_LICENSE"; then
 			AC_DEFINE_UNQUOTED([ZFS_META_LICENSE], ["$ZFS_META_LICENSE"],
 				[Define the project license.]
@@ -84,7 +106,7 @@ AC_DEFUN([ZFS_AC_META], [
 				AC_SUBST([ZFS_META_ALIAS])
 		fi
 
-		ZFS_META_DATA=_ZFS_AC_META_GETVAL([DATE]);
+		ZFS_META_DATA=_ZFS_AC_META_GETVAL([Date]);
 		if test -n "$ZFS_META_DATA"; then
 			AC_DEFINE_UNQUOTED([ZFS_META_DATA], ["$ZFS_META_DATA"],
 				[Define the project release date.] 
@@ -92,7 +114,7 @@ AC_DEFUN([ZFS_AC_META], [
 			AC_SUBST([ZFS_META_DATA])
 		fi
 
-		ZFS_META_AUTHOR=_ZFS_AC_META_GETVAL([AUTHOR]);
+		ZFS_META_AUTHOR=_ZFS_AC_META_GETVAL([Author]);
 		if test -n "$ZFS_META_AUTHOR"; then
 			AC_DEFINE_UNQUOTED([ZFS_META_AUTHOR], ["$ZFS_META_AUTHOR"],
 				[Define the project author.]
@@ -101,9 +123,9 @@ AC_DEFUN([ZFS_AC_META], [
 		fi
 
 		m4_pattern_allow([^LT_(CURRENT|REVISION|AGE)$])
-		ZFS_META_LT_CURRENT=_ZFS_AC_META_GETVAL([LT_CURRENT]);
-		ZFS_META_LT_REVISION=_ZFS_AC_META_GETVAL([LT_REVISION]);
-		ZFS_META_LT_AGE=_ZFS_AC_META_GETVAL([LT_AGE]);
+		ZFS_META_LT_CURRENT=_ZFS_AC_META_GETVAL([LT_Current]);
+		ZFS_META_LT_REVISION=_ZFS_AC_META_GETVAL([LT_Revision]);
+		ZFS_META_LT_AGE=_ZFS_AC_META_GETVAL([LT_Age]);
 		if test -n "$ZFS_META_LT_CURRENT" \
 				 -o -n "$ZFS_META_LT_REVISION" \
 				 -o -n "$ZFS_META_LT_AGE"; then
@@ -134,15 +156,18 @@ AC_DEFUN([ZFS_AC_META], [
 	]
 )
 
-AC_DEFUN([_ZFS_AC_META_GETVAL], 
-	[`perl -n\
-		-e "BEGIN { \\$key=shift @ARGV; }"\
-		-e "next unless s/^\s*\\$key@<:@:=@:>@//i;"\
-		-e "s/^((?:@<:@^'\"#@:>@*(?:(@<:@'\"@:>@)@<:@^\2@:>@*\2)*)*)#.*/\\@S|@1/;"\
-		-e "s/^\s+//;"\
-		-e "s/\s+$//;"\
-		-e "s/^(@<:@'\"@:>@)(.*)\1/\\@S|@2/;"\
-		-e "\\$val=\\$_;"\
-		-e "END { print \\$val if defined \\$val; }"\
-		'$1' $META`]dnl
+dnl # _ZFS_AC_META_GETVAL (KEY_NAME_OR_REGEX)
+dnl #
+dnl # Returns the META VALUE associated with the given KEY_NAME_OR_REGEX expr.
+dnl #
+dnl # Despite their resemblance to line noise,
+dnl #   the "@<:@" and "@:>@" constructs are quadrigraphs for "[" and "]".
+dnl #   <www.gnu.org/software/autoconf/manual/autoconf.html#Quadrigraphs>
+dnl #
+dnl # The "$[]1" and "$[]2" constructs prevent M4 parameter expansion
+dnl #   so a literal $1 and $2 will be passed to the resulting awk script,
+dnl #   whereas the "$1" will undergo M4 parameter expansion for the META key.
+dnl #
+AC_DEFUN([_ZFS_AC_META_GETVAL],
+	[`$AWK -F ':@<:@ \t@:>@+' '$[]1 ~ /^ *$1$/ { print $[]2; exit }' $META`]dnl
 )