1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
|
/*
* Mesa 3-D graphics library
* Version: 4.0
*
* Copyright (C) 1999 Brian Paul All Rights Reserved.
*
* Permission is hereby granted, free of charge, to any person obtaining a
* copy of this software and associated documentation files (the "Software"),
* to deal in the Software without restriction, including without limitation
* the rights to use, copy, modify, merge, publish, distribute, sublicense,
* and/or sell copies of the Software, and to permit persons to whom the
* Software is furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included
* in all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
* OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
* BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
* AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
* CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
*/
/*
* DOS/DJGPP device driver v1.4 for Mesa
*
* Copyright (C) 2002 - Borca Daniel
* Email : dborca@yahoo.com
* Web : http://www.geocities.com/dborca
*/
#include "x86/assyntax.h"
FILE("virtual.S")
/*
* extern void *vl_current_draw_buffer;
* extern int vl_current_width, vl_current_bytes;
*/
EXTERN _vl_current_draw_buffer
EXTERN _vl_current_width, _vl_current_bytes
SEG_TEXT
USE32
/* Desc: void v_clear8 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear8
_v_clear8:
MOV_L (REGOFF(4, ESP), EAX)
MOV_B (AL, AH)
PUSH_W (AX)
PUSH_W (AX)
POP_L (EAX)
jmp _v_clear_common
/* Desc: void v_clear16 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear16
_v_clear16:
MOV_L (REGOFF(4, ESP), EAX)
PUSH_W (AX)
PUSH_W (AX)
POP_L (EAX)
jmp _v_clear_common
/* Desc: void v_clear32 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear32
_v_clear32:
MOV_L (REGOFF(4, ESP), EAX)
ALIGNTEXT4
_v_clear_common:
MOV_L (CONTENT(_vl_current_bytes), ECX)
MOV_L (CONTENT(_vl_current_draw_buffer), EDX)
SHR_L (CONST(2), ECX)
ALIGNTEXT4
TLBL(0):
MOV_L (EAX, REGIND(EDX))
ADD_L (CONST(4), EDX)
DEC_L (ECX)
jnz TLBL(0)
RET
/* Desc: void v_clear8_mmx (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear8_mmx
_v_clear8_mmx:
#ifdef USE_MMX_ASM
MOVD (REGOFF(4, ESP), MM0)
PUNPCKLBW (MM0, MM0)
PUNPCKLWD (MM0, MM0)
jmp _v_clear_common_mmx
#endif
/* Desc: void v_clear16_mmx (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear16_mmx
_v_clear16_mmx:
#ifdef USE_MMX_ASM
MOVD (REGOFF(4, ESP), MM0)
PUNPCKLWD (MM0, MM0)
jmp _v_clear_common_mmx
#endif
/* Desc: void v_clear32_mmx (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear32_mmx
_v_clear32_mmx:
#ifdef USE_MMX_ASM
MOVD (REGOFF(4, ESP), MM0)
ALIGNTEXT4
_v_clear_common_mmx:
PUNPCKLDQ (MM0, MM0)
MOV_L (CONTENT(_vl_current_bytes), ECX)
MOV_L (CONTENT(_vl_current_draw_buffer), EDX)
SHR_L (CONST(3), ECX)
ALIGNTEXT4
TLBL(0):
MOVQ (MM0, REGIND(EDX))
ADD_L (CONST(8), EDX)
DEC_L (ECX)
jnz TLBL(0)
EMMS
#endif
RET
/* Desc: void v_clear24 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear24
_v_clear24:
MOV_L (CONST(0xaaaaaaab), EAX)
MUL_L (CONTENT(_vl_current_bytes))
MOV_L (REGOFF(4, ESP), EAX)
MOV_L (EDX, ECX)
PUSH_L (EBX)
MOV_L (CONTENT(_vl_current_draw_buffer), EDX)
SHR_L (CONST(1), ECX)
MOV_B (REGOFF(10,ESP), BL)
ALIGNTEXT4
TLBL(0):
MOV_W (AX, REGIND(EDX))
MOV_B (BL, REGOFF(2,EDX))
ADD_L (CONST(3), EDX)
DEC_L (ECX)
jnz TLBL(0)
POP_L (EBX)
RET
/* Desc: void v_clear24_mmx (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_clear24_mmx
_v_clear24_mmx:
#ifdef USE_MMX_ASM
MOV_L (REGOFF(4, ESP), EAX)
MOV_L (EAX, EDX)
MOV_L (EAX, ECX)
SHL_L (CONST(16), EDX)
ROR_L (CONST(8), ECX)
MOV_W (CX, DX)
ROR_L (CONST(16), ECX)
MOV_B (DH, CL)
SHL_L (CONST(8), EAX)
MOV_B (CH, AL)
ROR_L (CONST(8), EAX)
PUSH_L (EDX)
PUSH_L (EAX)
MOVQ (REGIND(ESP), MM0)
PUSH_L (ECX)
MOVQ (REGIND(ESP), MM1)
PUSH_L (EDX)
MOVQ (REGIND(ESP), MM2)
MOV_L (CONST(0xaaaaaaab), EAX)
MUL_L (CONTENT(_vl_current_bytes))
MOV_L (EDX, ECX)
MOV_L (CONTENT(_vl_current_draw_buffer), EDX)
SHR_L (CONST(4), ECX)
ALIGNTEXT4
TLBL(0):
MOVQ (MM0, REGIND(EDX))
MOVQ (MM1, REGOFF(8,EDX))
MOVQ (MM2, REGOFF(16,EDX))
ADD_L (CONST(24), EDX)
DEC_L (ECX)
jnz TLBL(0)
EMMS
ADD_L (CONST(16), ESP)
#endif
RET
/* Desc: void v_rect8 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_rect8
_v_rect8:
CLD
PUSH_L (ESI)
PUSH_L (EDI)
MOV_L (REGOFF(28, ESP), EAX)
MOV_L (CONTENT(_vl_current_width), ESI)
MOV_L (REGOFF(16, ESP), EDI)
MOV_B (AL, AH)
MOV_L (REGOFF(20, ESP), ECX)
IMUL_L (ESI, EDI)
MOV_L (REGOFF(24, ESP), EDX)
SUB_L (ECX, ESI)
ADD_L (REGOFF(12, ESP), EDI)
PUSH_W (AX)
PUSH_W (AX)
PUSH_SR (DS)
POP_SR (ES)
ADD_L (CONTENT(_vl_current_draw_buffer), EDI)
POP_L (EAX)
PUSH_L (EBX)
MOV_L (ECX, EBX)
AND_L (CONST(3), EBX)
ALIGNTEXT4
TLBL(0):
PUSH_L (ECX)
ALIGNTEXT4
TLBL(1):
SHR_L (CONST(2), ECX)
REP STOS_L
TEST_L (EBX, EBX)
jz TLBL(2)
MOV_L (EBX, ECX)
REP STOS_B
ALIGNTEXT4
TLBL(2):
POP_L (ECX)
ADD_L (ESI, EDI)
DEC_L (EDX)
jnz TLBL(0)
POP_L (EBX)
POP_L (EDI)
POP_L (ESI)
RET
/* Desc: void v_rect16 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_rect16
_v_rect16:
CLD
PUSH_L (ESI)
PUSH_L (EDI)
MOV_L (REGOFF(28, ESP), EAX)
MOV_L (CONTENT(_vl_current_width), ESI)
MOV_L (REGOFF(16, ESP), EDI)
MOV_L (REGOFF(20, ESP), ECX)
IMUL_L (ESI, EDI)
MOV_L (REGOFF(24, ESP), EDX)
SUB_L (ECX, ESI)
ADD_L (REGOFF(12, ESP), EDI)
PUSH_W (AX)
SHL_L (CONST(1), ESI)
PUSH_W (AX)
SHL_L (CONST(1), EDI)
PUSH_SR (DS)
POP_SR (ES)
ADD_L (CONTENT(_vl_current_draw_buffer), EDI)
POP_L (EAX)
ALIGNTEXT4
TLBL(0):
PUSH_L (ECX)
ALIGNTEXT4
TLBL(1):
SHR_L (CONST(1), ECX)
REP STOS_L
jnc TLBL(2)
STOS_W
ALIGNTEXT4
TLBL(2):
POP_L (ECX)
ADD_L (ESI, EDI)
DEC_L (EDX)
jnz TLBL(0)
POP_L (EDI)
POP_L (ESI)
RET
/* Desc: void v_rect24 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_rect24
_v_rect24:
PUSH_L (ESI)
PUSH_L (EDI)
MOV_L (REGOFF(28, ESP), EAX)
MOV_L (CONTENT(_vl_current_width), ESI)
MOV_L (REGOFF(16, ESP), EDI)
MOV_L (REGOFF(20, ESP), ECX)
IMUL_L (ESI, EDI)
MOV_L (REGOFF(24, ESP), EDX)
SUB_L (ECX, ESI)
ADD_L (REGOFF(12, ESP), EDI)
LEA_L (REGBIS(ESI, ESI, 2), ESI)
PUSH_L (EBX)
LEA_L (REGBIS(EDI, EDI, 2), EDI)
MOV_L (EAX, EBX)
ADD_L (CONTENT(_vl_current_draw_buffer), EDI)
SHR_L (CONST(16), EBX)
ALIGNTEXT4
TLBL(0):
PUSH_L (ECX)
ALIGNTEXT4
TLBL(1):
MOV_W (AX, REGIND(EDI))
MOV_B (BL, REGOFF(2,EDI))
ADD_L (CONST(3), EDI)
DEC_L (ECX)
jnz TLBL(1)
POP_L (ECX)
ADD_L (ESI, EDI)
DEC_L (EDX)
jnz TLBL(0)
POP_L (EBX)
POP_L (EDI)
POP_L (ESI)
RET
/* Desc: void v_rect32 (int color);
*
* In : color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_rect32
_v_rect32:
PUSH_L (ESI)
PUSH_L (EDI)
MOV_L (CONTENT(_vl_current_width), ESI)
MOV_L (REGOFF(16, ESP), EDI)
MOV_L (REGOFF(20, ESP), ECX)
IMUL_L (ESI, EDI)
MOV_L (REGOFF(24, ESP), EDX)
SUB_L (ECX, ESI)
ADD_L (REGOFF(12, ESP), EDI)
SHL_L (CONST(2), ESI)
SHL_L (CONST(2), EDI)
MOV_L (REGOFF(28, ESP), EAX)
ADD_L (CONTENT(_vl_current_draw_buffer), EDI)
ALIGNTEXT4
TLBL(0):
PUSH_L (ECX)
ALIGNTEXT4
TLBL(1):
MOV_L (EAX, REGIND(EDI))
ADD_L (CONST(4), EDI)
DEC_L (ECX)
jnz TLBL(1)
POP_L (ECX)
ADD_L (ESI, EDI)
DEC_L (EDX)
jnz TLBL(0)
POP_L (EDI)
POP_L (ESI)
RET
/* Desc: void v_putpixel8 (unsigned int offset, int color);
*
* In : offset within buffer, color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_putpixel8
_v_putpixel8:
MOV_L (REGOFF(8, ESP), ECX)
MOV_L (REGOFF(4, ESP), EDX)
MOV_L (CONTENT(_vl_current_draw_buffer), EAX)
MOV_B (CL, REGBI(EAX,EDX))
RET
/* Desc: void v_putpixel16 (unsigned int offset, int color);
*
* In : offset within buffer, color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_putpixel16
_v_putpixel16:
MOV_L (REGOFF(8, ESP), ECX)
MOV_L (REGOFF(4, ESP), EDX)
MOV_L (CONTENT(_vl_current_draw_buffer), EAX)
MOV_W (CX, REGBIS(EAX,EDX,2))
RET
/* Desc: void v_putpixel24 (unsigned int offset, int color);
*
* In : offset within buffer, color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_putpixel24
_v_putpixel24:
MOV_L (REGOFF(4, ESP), EAX)
MOV_L (REGOFF(8, ESP), EDX)
MOV_L (CONTENT(_vl_current_draw_buffer), ECX)
LEA_L (REGBIS(EAX,EAX,2), EAX)
MOV_W (DX, REGBI(ECX,EAX))
SHR_L (CONST(16), EDX)
MOV_B (DL, REGBID(ECX,EAX,2))
RET
/* Desc: void v_putpixel32 (unsigned int offset, int color);
*
* In : offset within buffer, color
* Out : -
*
* Note: uses current draw buffer
*/
ALIGNTEXT32
GLOBL _v_putpixel32
_v_putpixel32:
MOV_L (REGOFF(8, ESP), ECX)
MOV_L (REGOFF(4, ESP), EDX)
MOV_L (CONTENT(_vl_current_draw_buffer), EAX)
MOV_L (ECX, REGBIS(EAX,EDX,4))
RET
|
