meson: build gallium based osmesa

This has been tested with the osdemo from mesa-demos

v2: - Add SELinux dependency
    - fix typo GALLIUM_LLVM -> GALLIUM_LLVMPIPE

Signed-off-by: Dylan Baker <[email protected]>
Reviewed-by: Eric Engestrom <[email protected]>

3 files changed, 102 insertions, 1 deletions

diff --git a/src/gallium/meson.build b/src/gallium/meson.build
index e0941103b93..6edfe80321d 100644
--- a/src/gallium/meson.build
+++ b/src/gallium/meson.build
@@ -66,6 +66,9 @@ if with_gallium_imx
   subdir('winsys/imx/drm')
 endif
 subdir('state_trackers/dri')
+if with_osmesa == 'gallium'
+  subdir('state_trackers/osmesa')
+endif
 # TODO: i915
 # TODO: SVGA
 # TODO: r300
@@ -77,9 +80,11 @@ subdir('state_trackers/dri')
 if with_dri and with_gallium
   subdir('targets/dri')
 endif
+if with_osmesa == 'gallium'
+  subdir('targets/osmesa')
+endif
 # TODO: xlib-glx
 # TODO: OMX
-# TODO: osmesa
 # TODO: VA
 # TODO: vdpau
 # TODO: xa
diff --git a/src/gallium/state_trackers/osmesa/meson.build b/src/gallium/state_trackers/osmesa/meson.build
new file mode 100644
index 00000000000..dacf10512d6
--- /dev/null
+++ b/src/gallium/state_trackers/osmesa/meson.build
@@ -0,0 +1,28 @@
+# Copyright © 2017 Intel Corporation
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+libosmesa_st = static_library(
+  'osmesa_st',
+  'osmesa.c',
+  c_args : ['-DGALLIUM_SOFTPIPE', '-DGALLIUM_TRACE'],
+  include_directories : [
+    inc_include, inc_src, inc_gallium, inc_gallium_aux, inc_mapi, inc_mesa,
+  ],
+)
diff --git a/src/gallium/targets/osmesa/meson.build b/src/gallium/targets/osmesa/meson.build
new file mode 100644
index 00000000000..b4b3911ffd5
--- /dev/null
+++ b/src/gallium/targets/osmesa/meson.build
@@ -0,0 +1,68 @@
+# Copyright © 2017 Intel Corporation
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+osmesa_link_with = []
+osmesa_link_args = []
+osmesa_comp_args = ['-DGALLIUM_SOFTPIPE', '-DGALLIUM_TRACE']
+osmesa_deps = []
+
+if with_shared_glapi
+  osmesa_link_with += libglapi
+endif
+if with_ld_version_script
+  osmesa_link_args += [
+    '-Wl,--version-script', join_paths(meson.current_source_dir(), 'osmesa.sym')
+  ]
+endif
+
+if with_llvm
+  osmesa_comp_args += '-DGALLIUM_LLVMPIPE'
+  osmesa_deps += dep_llvm
+  osmesa_link_with += libllvmpipe
+endif
+# TODO: swr
+
+libosmesa = shared_library(
+  osmesa_lib_name,
+  'target.c',
+  c_args : [c_vis_args, osmesa_comp_args],
+  cpp_args : [cpp_vis_args, osmesa_comp_args],
+  link_args : [ld_args_gc_sections, osmesa_link_args],
+  include_directories : [
+    inc_include, inc_src, inc_gallium, inc_gallium_aux, inc_gallium_winsys,
+    inc_gallium_drivers,
+  ],
+  link_whole : [libosmesa_st],
+  link_with : [
+    libmesa_gallium, libgallium, libglapi_static, libws_null, libtrace,
+    libsoftpipe, osmesa_link_with,
+  ],
+  dependencies : [dep_selinux, dep_thread, dep_clock, dep_unwind, osmesa_deps],
+  version : '8.0.0',
+  install : true,
+)
+
+pkg.generate(
+  name : 'osmesa',
+  description : 'Mesa Off-screen Rendering Library',
+  version : '8',
+  libraries : libosmesa,
+  libraries_private : gl_priv_libs,
+)