mapi/vgapi: Add SConscript for Windows build.

1 files changed, 55 insertions, 0 deletions

diff --git a/src/mapi/vgapi/SConscript b/src/mapi/vgapi/SConscript
new file mode 100644
index 00000000000..f000c6105b3
--- /dev/null
+++ b/src/mapi/vgapi/SConscript
@@ -0,0 +1,55 @@
+#######################################################################
+# SConscript for vgapi
+
+from sys import executable as python_cmd
+
+Import('*')
+
+if env['platform'] != 'winddk':
+
+	env = env.Clone()
+
+	vgapi_header = env.CodeGenerate(
+		target = '#src/mapi/vgapi/vgapi_tmp.h',
+		script = '../mapi/mapi_abi.py',
+		source = 'vgapi.csv',
+		command = python_cmd + ' $SCRIPT -i vgapi/vgapi_defines.h $SOURCE > $TARGET'
+	)
+
+	env.Append(CPPDEFINES = [
+		'MAPI_ABI_HEADER=\\"vgapi/vgapi_tmp.h\\"',
+		'KHRONOS_DLL_EXPORTS',
+	])
+
+	env.Append(CPPPATH = [
+		'#/include',
+		'#/src/mapi',
+	])
+
+	mapi_sources = [
+		'entry.c',
+		'mapi.c',
+		'stub.c',
+		'table.c',
+		'u_current.c',
+		'u_execmem.c',
+		'u_thread.c',
+	]
+
+	vgapi_objects = []
+	for s in mapi_sources:
+		o = env.Object(s[:-2], '../mapi/' + s)
+		vgapi_objects.append(o)
+
+	env.Depends(vgapi_objects, vgapi_header)
+
+	openvg = env.SharedLibrary(
+		target = 'libOpenVG',
+		source = vgapi_objects,
+	)
+
+	env.InstallSharedLibrary(openvg, version=(1, 0, 0))
+
+	vgapi = [env.FindIxes(openvg, 'LIBPREFIX', 'LIBSUFFIX')]
+
+	Export(['vgapi', 'vgapi_header'])