meson: build "radv" vulkan driver for radeon hardware

This builds, installs, and has been tested on a r290x (Hawaii) with the Vulkan
CTS. It dies horribly in a fire at the same point for the meson build as the
autotools build.

v2: - enable radv by default
    - add shader cache support and enforce that it's built for radv
v3: - Fix typo in meson_options (Nicholas)
    - strip trailing 'svn' from llvm version before setting the version
      preprocessor flag (Bas)
    - Check for LLVM module requirements

Signed-off-by: Dylan Baker <[email protected]>
Reviewed-by: Bas Nieuwenhuizen <[email protected]>

1 files changed, 124 insertions, 0 deletions

diff --git a/src/amd/vulkan/meson.build b/src/amd/vulkan/meson.build
new file mode 100644
index 00000000000..02a2703a5c1
--- /dev/null
+++ b/src/amd/vulkan/meson.build
@@ -0,0 +1,124 @@
+# Copyright © 2017 Intel Corporation
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in
+# all copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+radv_entrypoints = custom_target(
+  'radv_entrypoints.[ch]',
+  input : ['radv_entrypoints_gen.py', vk_api_xml],
+  output : ['radv_entrypoints.h', 'radv_entrypoints.c'],
+  command : [prog_python2, '@INPUT0@', '--xml', '@INPUT1@',
+             '--outdir', meson.current_build_dir()],
+)
+
+vk_format_table_c = custom_target(
+  'vk_format_table.c',
+  input : ['vk_format_table.py', 'vk_format_layout.csv'],
+  output : 'vk_format_table.c',
+  command : [prog_python2, '@INPUT@'],
+  depend_files : files('vk_format_parse.py'),
+  capture : true,
+)
+
+libradv_files = files(
+  'winsys/amdgpu/radv_amdgpu_bo.c',
+  'winsys/amdgpu/radv_amdgpu_bo.h',
+  'winsys/amdgpu/radv_amdgpu_cs.c',
+  'winsys/amdgpu/radv_amdgpu_cs.h',
+  'winsys/amdgpu/radv_amdgpu_surface.c',
+  'winsys/amdgpu/radv_amdgpu_surface.h',
+  'winsys/amdgpu/radv_amdgpu_winsys.c',
+  'winsys/amdgpu/radv_amdgpu_winsys.h',
+  'winsys/amdgpu/radv_amdgpu_winsys_public.h',
+  'radv_cmd_buffer.c',
+  'radv_cs.h',
+  'radv_debug.c',
+  'radv_debug.h',
+  'radv_device.c',
+  'radv_descriptor_set.c',
+  'radv_descriptor_set.h',
+  'radv_formats.c',
+  'radv_image.c',
+  'radv_meta.c',
+  'radv_meta.h',
+  'radv_meta_blit.c',
+  'radv_meta_blit2d.c',
+  'radv_meta_buffer.c',
+  'radv_meta_bufimage.c',
+  'radv_meta_clear.c',
+  'radv_meta_copy.c',
+  'radv_meta_decompress.c',
+  'radv_meta_fast_clear.c',
+  'radv_meta_resolve.c',
+  'radv_meta_resolve_cs.c',
+  'radv_meta_resolve_fs.c',
+  'radv_pass.c',
+  'radv_pipeline.c',
+  'radv_pipeline_cache.c',
+  'radv_private.h',
+  'radv_radeon_winsys.h',
+  'radv_shader.c',
+  'radv_shader.h',
+  'radv_query.c',
+  'radv_util.c',
+  'radv_util.h',
+  'radv_wsi.c',
+  'si_cmd_buffer.c',
+  'vk_format.h',
+)
+
+radv_deps = []
+radv_flags = []
+
+if with_platform_x11
+  radv_deps += dep_xcb_dri3
+  radv_flags += [
+    '-DVK_USE_PLATFORM_XCB_KHR',
+    '-DVK_USE_PLATFORM_XLIB_KHR',
+  ]
+  libradv_files += files('radv_wsi_x11.c')
+endif
+
+if with_platform_wayland
+  radv_deps += dep_wayland_client
+  radv_flags += '-DVK_USE_PLATFORM_WAYLAND_KHR'
+  libradv_files += files('radv_wsi_wayland.c')
+endif
+
+libvulkan_radeon = shared_library(
+  'vulkan_radeon',
+  [libradv_files, radv_entrypoints, nir_opcodes_h, vk_format_table_c],
+  include_directories : [inc_common, inc_amd, inc_amd_common, inc_compiler,
+                         inc_vulkan_util, inc_vulkan_wsi],
+  link_with : [libamd_common, libamdgpu_addrlib, libvulkan_util,
+               libvulkan_wsi, libnir, libmesa_util],
+  dependencies : [dep_llvm, dep_libdrm_amdgpu, dep_thread, dep_elf, dep_dl,
+                  dep_m, dep_valgrind],
+  c_args : [c_vis_args, no_override_init_args, radv_flags],
+  link_args : [ld_args_bsymbolic, ld_args_gc_sections],
+  install : true,
+)
+
+radv_data = configuration_data()
+radv_data.set('install_libdir', join_paths(get_option('prefix'), get_option('libdir')))
+configure_file(
+  configuration : radv_data,
+  input : 'radeon_icd.json.in',
+  output : 'radeon_icd.@[email protected]'.format(target_machine.cpu()),
+  install_dir : with_vulkan_icd_dir,
+)