1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
|
/*************************************************
* SHA-160 Source File *
* (C) 1999-2006 The Botan Project *
*************************************************/
#include <botan/asm_macr.h>
START_LISTING(sha1core.S)
FUNCTION(sha160_core)
PUSH(EBP)
PUSH(EDI)
PUSH(ESI)
PUSH(EBX)
#define PUSHED 4
MOV(ARG(2), EBP)
MOV(ARG(3), EDI)
ZEROIZE(ESI)
ALIGN
.LOAD_INPUT_LOOP:
ADD(IMM(4), ESI)
MOV(ARRAY(EBP, 0), EAX)
MOV(ARRAY(EBP, 1), EBX)
MOV(ARRAY(EBP, 2), ECX)
MOV(ARRAY(EBP, 3), EDX)
ADD(IMM(16), EBP)
BSWAP(EAX)
BSWAP(EBX)
BSWAP(ECX)
BSWAP(EDX)
movl EAX, -16(EDI,ESI,4)
movl EBX, -12(EDI,ESI,4)
movl ECX, -8(EDI,ESI,4)
movl EDX, -4(EDI,ESI,4)
LOOP_UNTIL(ESI, IMM(16), .LOAD_INPUT_LOOP)
leal 64(EDI), EBP
ALIGN
.EXPANSION_LOOP:
ADD(IMM(4), ESI)
ZEROIZE(EAX)
movl -4(EBP), EBX
movl -8(EBP), ECX
movl -12(EBP), EDX
xorl -20(EBP), EAX
xorl -24(EBP), EBX
xorl -28(EBP), ECX
xorl -32(EBP), EDX
xorl -44(EBP), EAX
xorl -48(EBP), EBX
xorl -52(EBP), ECX
xorl -56(EBP), EDX
xorl -52(EBP), EAX
xorl -56(EBP), EBX
xorl -60(EBP), ECX
xorl -64(EBP), EDX
roll $1, EDX
roll $1, ECX
movl EDX, (EBP)
roll $1, EBX
movl ECX, 4(EBP)
xorl EDX, EAX
movl EBX, 8(EBP)
roll $1, EAX
movl EAX, 12(EBP)
addl $16, EBP
cmpl $80, ESI
LOOP_UNTIL(ESI, IMM(80), .EXPANSION_LOOP)
movl 20(%esp), EBP
movl 0(EBP), EAX
movl 4(EBP), EBX
movl 8(EBP), ECX
movl 12(EBP), EDX
movl 16(EBP), ESI
#define MAGIC1 0x5A827999
#define MAGIC2 0x6ED9EBA1
#define MAGIC3 0x8F1BBCDC
#define MAGIC4 0xCA62C1D6
#define F1(A, B, C, D, E, TEMP, MSG) \
addl 4*MSG(EDI), E ; \
movl C, TEMP ; \
roll $5, A ; \
xorl D, TEMP ; \
addl A, E ; \
andl B, TEMP ; \
rorl $2, B ; \
xorl D, TEMP ; \
leal MAGIC1(E,TEMP,1), E ; \
rorl $5, A ;
#define F2_OR_F4(A, B, C, D, E, TEMP, MSG, MAGIC) \
addl 4*MSG(EDI), E ; \
movl B, TEMP ; \
roll $5, A ; \
xorl D, TEMP ; \
addl A, E ; \
xorl C, TEMP ; \
rorl $2, B ; \
leal MAGIC(E,TEMP,1), E ; \
rorl $5, A ;
#define F3(A, B, C, D, E, TEMP, MSG) \
addl 4*MSG(EDI), E ; \
movl B, TEMP ; \
roll $5, A ; \
orl C, TEMP ; \
movl B, 4*MSG(EDI) ; \
andl D, TEMP ; \
andl C, 4*MSG(EDI) ; \
orl 4*MSG(EDI), TEMP ; \
addl A, E ; \
leal MAGIC3(E,TEMP,1), E ; \
rorl $2, B ; \
rorl $5, A ;
#define F2(A, B, C, D, E, TEMP, MSG) \
F2_OR_F4(A, B, C, D, E, TEMP, MSG, MAGIC2)
#define F4(A, B, C, D, E, TEMP, MSG) \
F2_OR_F4(A, B, C, D, E, TEMP, MSG, MAGIC4)
#define F_BLOCK(F, MSG) \
F(EAX, EBX, ECX, EDX, ESI, EBP, (MSG+0)) \
F(ESI, EAX, EBX, ECX, EDX, EBP, (MSG+1)) \
F(EDX, ESI, EAX, EBX, ECX, EBP, (MSG+2)) \
F(ECX, EDX, ESI, EAX, EBX, EBP, (MSG+3)) \
F(EBX, ECX, EDX, ESI, EAX, EBP, (MSG+4))
F_BLOCK(F1, 0)
F_BLOCK(F1, 5)
F_BLOCK(F1, 10)
F_BLOCK(F1, 15)
F_BLOCK(F2, 20)
F_BLOCK(F2, 25)
F_BLOCK(F2, 30)
F_BLOCK(F2, 35)
F_BLOCK(F3, 40)
F_BLOCK(F3, 45)
F_BLOCK(F3, 50)
F_BLOCK(F3, 55)
F_BLOCK(F4, 60)
F_BLOCK(F4, 65)
F_BLOCK(F4, 70)
F_BLOCK(F4, 75)
movl 20(%esp), EBP
addl EAX, 0(EBP)
addl EBX, 4(EBP)
addl ECX, 8(EBP)
addl EDX, 12(EBP)
addl ESI, 16(EBP)
popl EBX
popl ESI
popl EDI
popl EBP
ret
|
