1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
|
/*************************************************
* SHA-160 Source File *
* (C) 1999-2006 The Botan Project *
*************************************************/
#include <botan/asm_macr.h>
START_LISTING(sha1core.S)
FUNCTION(sha160_core)
PUSH(EBP)
PUSH(EDI)
PUSH(ESI)
PUSH(EBX)
#define PUSHED 4
ASSIGN(EBP, ARG(2))
ASSIGN(EDI, ARG(3))
ZEROIZE(ESI)
START_LOOP(.LOAD_INPUT)
ADD_IMM(ESI, 4)
ASSIGN(EAX, ARRAY(EBP, 0))
ASSIGN(EBX, ARRAY(EBP, 1))
ASSIGN(ECX, ARRAY(EBP, 2))
ASSIGN(EDX, ARRAY(EBP, 3))
ADD_IMM(EBP, 16)
BSWAP(EAX)
BSWAP(EBX)
BSWAP(ECX)
BSWAP(EDX)
ASSIGN(-16(EDI,ESI,4), EAX)
ASSIGN(-12(EDI,ESI,4), EBX)
ASSIGN( -8(EDI,ESI,4), ECX)
ASSIGN( -4(EDI,ESI,4), EDX)
LOOP_UNTIL(ESI, IMM(16), .LOAD_INPUT)
ADD2_IMM(EBP, EDI, 64)
START_LOOP(.EXPANSION)
ADD_IMM(ESI, 4)
ZEROIZE(EAX)
ASSIGN(EBX, ARRAY(EBP, -1))
ASSIGN(ECX, ARRAY(EBP, -2))
ASSIGN(EDX, ARRAY(EBP, -3))
XOR(ARRAY(EBP, -5), EAX)
XOR(ARRAY(EBP, -6), EBX)
XOR(ARRAY(EBP, -7), ECX)
XOR(ARRAY(EBP, -8), EDX)
XOR(ARRAY(EBP, -11), EAX)
XOR(ARRAY(EBP, -12), EBX)
XOR(ARRAY(EBP, -13), ECX)
XOR(ARRAY(EBP, -14), EDX)
XOR(ARRAY(EBP, -13), EAX)
XOR(ARRAY(EBP, -14), EBX)
XOR(ARRAY(EBP, -15), ECX)
XOR(ARRAY(EBP, -16), EDX)
ROTL_IMM(EDX, 1)
ROTL_IMM(ECX, 1)
ROTL_IMM(EBX, 1)
XOR(EDX, EAX)
ROTL_IMM(EAX, 1)
ASSIGN(ARRAY(EBP, 0), EDX)
ASSIGN(ARRAY(EBP, 1), ECX)
ASSIGN(ARRAY(EBP, 2), EBX)
ASSIGN(ARRAY(EBP, 3), EAX)
ADD_IMM(EBP, 16)
LOOP_UNTIL(ESI, IMM(80), .EXPANSION)
ASSIGN(EBP, ARG(1))
ASSIGN(EAX, ARRAY(EBP, 0))
ASSIGN(EBX, ARRAY(EBP, 1))
ASSIGN(ECX, ARRAY(EBP, 2))
ASSIGN(EDX, ARRAY(EBP, 3))
ASSIGN(ESI, ARRAY(EBP, 4))
#define MAGIC1 0x5A827999
#define MAGIC2 0x6ED9EBA1
#define MAGIC3 0x8F1BBCDC
#define MAGIC4 0xCA62C1D6
#define F1(A, B, C, D, E, TEMP, MSG) \
ADD(ARRAY(EDI, MSG), E) ; \
ASSIGN(TEMP, C) ; \
ROTL_IMM(A, 5) ; \
XOR(D, TEMP) ; \
ADD(A, E) ; \
AND(B, TEMP) ; \
ROTR_IMM(B, 2) ; \
XOR(D, TEMP) ; \
leal MAGIC1(E,TEMP,1), E ; \
ROTR_IMM(A, 5) ;
#define F2_OR_F4(A, B, C, D, E, TEMP, MSG, MAGIC) \
ADD(ARRAY(EDI, MSG), E) ; \
ASSIGN(TEMP, B) ; \
ROTL_IMM(A, 5) ; \
XOR(D, TEMP) ; \
ADD(A, E) ; \
XOR(C, TEMP) ; \
ROTR_IMM(B, 2) ; \
leal MAGIC(E,TEMP,1), E ; \
ROTR_IMM(A, 5) ;
#define F3(A, B, C, D, E, TEMP, MSG) \
ADD(ARRAY(EDI, MSG), E) ; \
ASSIGN(TEMP, B) ; \
ROTL_IMM(A, 5) ; \
OR(C, TEMP) ; \
ASSIGN(ARRAY(EDI, MSG), B) ; \
AND(D, TEMP) ; \
AND(C, ARRAY(EDI, MSG)) ; \
OR(ARRAY(EDI, MSG), TEMP) ; \
ADD(A, E) ; \
leal MAGIC3(E,TEMP,1), E ; \
ROTR_IMM(B, 2) ; \
ROTR_IMM(A, 5) ;
#define F2(A, B, C, D, E, TEMP, MSG) \
F2_OR_F4(A, B, C, D, E, TEMP, MSG, MAGIC2)
#define F4(A, B, C, D, E, TEMP, MSG) \
F2_OR_F4(A, B, C, D, E, TEMP, MSG, MAGIC4)
#define F_BLOCK(F, MSG) \
F(EAX, EBX, ECX, EDX, ESI, EBP, (MSG+0)) \
F(ESI, EAX, EBX, ECX, EDX, EBP, (MSG+1)) \
F(EDX, ESI, EAX, EBX, ECX, EBP, (MSG+2)) \
F(ECX, EDX, ESI, EAX, EBX, EBP, (MSG+3)) \
F(EBX, ECX, EDX, ESI, EAX, EBP, (MSG+4))
F_BLOCK(F1, 0)
F_BLOCK(F1, 5)
F_BLOCK(F1, 10)
F_BLOCK(F1, 15)
F_BLOCK(F2, 20)
F_BLOCK(F2, 25)
F_BLOCK(F2, 30)
F_BLOCK(F2, 35)
F_BLOCK(F3, 40)
F_BLOCK(F3, 45)
F_BLOCK(F3, 50)
F_BLOCK(F3, 55)
F_BLOCK(F4, 60)
F_BLOCK(F4, 65)
F_BLOCK(F4, 70)
F_BLOCK(F4, 75)
ASSIGN(EBP, ARG(1))
ADD(EAX, ARRAY(EBP, 0))
ADD(EBX, ARRAY(EBP, 1))
ADD(ECX, ARRAY(EBP, 2))
ADD(EDX, ARRAY(EBP, 3))
ADD(ESI, ARRAY(EBP, 4))
POP(EBX)
POP(ESI)
POP(EDI)
POP(EBP)
ret
|
